~ start
- bisher gelerntes nochmal ansehen
	=> recap
- Fragen zum EU AI Act stellen [if DialogueState.enableLLM]
	$> openChatBot()
- Hilfe zum Spiel (Steuerung, aktuelle Aufabe, ...)
	=> help
- gesamter Text des EU AI Acts (öffnet Link im Browser)
	$> openAIActinBrowser()
- gesamter Text der DSGVO (öffnet Link im Browser)
	$> openDSGVOinBrowser()
- Musik an/aus
	$> toggle_music()
- Schließen
	=> END
=> END

~ recap
- Alien-Dialoge wiederholen
	=> AI
- Mögliche Anwendungen von KI [if DialogueState.batteriesFlag]
	=> applications
- Risikostufen [if DialogueState.orderingGameFlag]
	=> risks
- personenbezogene Daten [if DialogueState.personalDataFlag]
	=> personalData
- zurück
	=> start

~ AI
- Alien001 [if DialogueState.alienFlags[1]]
	Alien001: Ich finde es schwierig künstliche Intelligenz zu definieren. Die Menschen sind sich ja nichtmal einig was Intelligenz ist.
	=> AI
- Alien002 [if DialogueState.alienFlags[2]]
	Alien002: Künstliche Intelligenz lernt aus großen Datenmengen. Die Ergebnisse sind nicht deterministisch, also es kommt nie genau das gleiche raus, wenn ich einen Algorithmus zweimal lernen lasse.
	=> AI
- Alien003 [if DialogueState.alienFlags[3]]
	Alien003: Modelle Künstlicher Intelligenz können komplexe Funktionen über sehr viele Parameter abbilden. Die Parameter werden aus Daten gelernt.
	=> AI
- Alien004 [if DialogueState.alienFlags[4]]
	Alien004: In der Stanford Enzyklopädie für Philosophie steht: Künstliche Intelligenz (KI) ist das Gebiet, das sich mit der Erschaffung künstlicher Tiere (oder zumindest künstlicher Lebewesen, die – in geeigneten Kontexten – wie Tiere erscheinen) und für viele auch künstlicher Personen (oder zumindest künstlicher Lebewesen, die – in geeigneten Kontexten – wie Personen erscheinen) befasst.
	Ich glaube das heißt KI möchte Lebewesen erschaffen, die für Menschen nicht von natürlichen Lebewesen unterscheidbar sind.
	=> AI
- Alien005 [if DialogueState.alienFlags[5]]
	Alien005: Die Stanford 100 year study of AI sagt: Künstliche Intelligenz ist die Tätigkeit, die darauf abzielt, Maschinen intelligent zu machen, und Intelligenz ist die Eigenschaft, die es einem Wesen ermöglicht, in seiner Umgebung angemessen und vorausschauend zu handeln.
	=> AI
- zurück
	=> recap

~ applications
Helfer: Spamfilter, Diagnose von Krankheiten auf MRT-Bildern, Chatbots, biometrische Überwachung im öffentlichen Raum.
=> recap

~ risks
Der EU AI Act bewertet KI Systeme in vier Risikostufen, von minimalem bis zu inakzeptablem Risiko für Grundrechte und Sicherheit.
Je höher das Risiko, umso strenger die Regulierung. KI Systeme mit inakzeptablem Risiko sind verboten.
~ risklevels
if DialogueState.seen
	=> risklevels1
else
	set DialogueState.seen = true
	=> risklevels0

~ risklevels0
Die vier Risikostufen: [speed=1]Lernen Sie nun die einzelnen Stufen genauer kennen. Eine der Stufen mit der Maus oder den Pfeiltasten auswählen und klicken/Enter/Leertaste drücken. 
- Minimales Risiko
	Minimales Risiko: Keine spezifischen Anforderungen. \nEin Beispiel für diese Kategorie wäre ein Schachcomputer.
	=> risklevels
- Geringes Risiko
	Geringes Risiko: Informationspflicht über die Benutzung der KI. \nEin Beispiel für diese Kategorie wäre ein Programmierbot.
	=> risklevels
- Hohes Risiko
	Hohes Risiko: Strenge Anforderungen an Transparenz, Dokumentation, Überwachung des Systems durch Menschen! \nEin Beispiel für diese Kategorie wäre ein KI-System, dass automatisch Arbeiten von Studierenden oder Schülern/Schülerinnen bewertet.
	=> risklevels
- Inakzeptables Risiko
	Inakzeptables Risiko: KI ist verboten! \nEin Beispiel für diese Kategorie wäre der Einsatz eines KI-Systems, dass das Risiko, dass eine Person in Zukunft eine Straftat begeht, vorhersagt.
	=> risklevels
- Zurück
	=> recap
	
~ risklevels1
Die vier Risikostufen: [speed=-1]Lernen Sie nun die einzelnen Stufen genauer kennen.
- Minimales Risiko
	Minimales Risiko: Keine spezifischen Anforderungen. \nEin Beispiel für diese Kategorie wäre ein Schachcomputer.
	=> risklevels
- Geringes Risiko
	Geringes Risiko: Informationspflicht über die Benutzung der KI. \nEin Beispiel für diese Kategorie wäre ein Programmierbot.
	=> risklevels
- Hohes Risiko
	Hohes Risiko: Strenge Anforderungen an Transparenz, Dokumentation, Überwachung des Systems durch Menschen! \nEin Beispiel für diese Kategorie wäre ein KI-System, dass automatisch Arbeiten von Studierenden oder Schülern/Schülerinnen bewertet.
	=> risklevels
- Inakzeptables Risiko
	Inakzeptables Risiko: KI ist verboten! \nEin Beispiel für diese Kategorie wäre der Einsatz eines KI-Systems, dass das Risiko, dass eine Person in Zukunft eine Straftat begeht, vorhersagt.
	=> risklevels
- Zurück
	=> recap
	
~ personalData
: KI im Alltag: Wahrscheinlich sind die bisherigen Beispiele für Sie im Berufsalltag noch nicht relevant, sicher kennen Sie aber und vielleicht nutzen Sie auch schon sogenannte Sprachmodelle, die uns Fragen beantworten, Texte schreiben, übersetzen und vieles mehr. Beispiele hierfür sind ChatGPT oder Gemini.
: Erste wichtige Regel: Jegliche Eingabe von personenbezogenen Daten in kommerzielle Sprachmodelle ist verboten (laut Datenschutzgrundverordnung, hier ist nicht unbedingt der AI Act die Grundlage). Wollen Sie sich davor schützen, dass aus Ihren Anfragen von Firmen Rückschlüsse über Ihre eigene Person gezogen werden, nutzen sie am besten gar keine kommerziellen Modelle.
: Glücklicherweise bietet die Universität Greifswald  eine Alternative. Das Rechenzentrum stellt uns eine ganze Reihe von Sprachmodellen zur Verfügung, die auf der Infrastruktur der Universität installiert sind und Daten nicht nach außen lassen. Ihre Anfragen sind damit so sicher wie Ihre Daten, die Sie in der Cloud der Universität speichern. https://open-webui.wolke.uni-greifswald.de
: Dürfen Sie hier jetzt persönliche Daten eingeben? Nein, nur mit Zustimmung der Person, von der die Daten stammen, und unter der Voraussetzung, dass die Person vollständig informiert ist und genau der Eingabe für diesen Zweck zugestimmt hat.
: Ein weiteres Problem mit Ki und Sprachmodellen ist Ihre Zuverlässigkeit. Seien Sie daher kritisch bei jeder Information, die Ihnen ein Modell liefert und prüfen Sie nach. Nutzen Sie z.B. nicht ungelesen Texte für Emails oder ungeprüfte Informationen für Vorträge.
: Was sind denn eigentlich personenbezogene Daten?
: Alle Informationen, die Sie in ein KI System eingeben, sind Daten. Personenbezogene Daten können Menschen direkt oder indirekt (durch Zusammenführung verschiedener Daten) identifizieren.
: Direkt identifizierende Daten sind z.B. Name, Adresse, Personalausweisnummer. Indirekt identifizierende Informationen sind z.B. Geburtsdatum, Geschlecht, Standortdaten, Online-Kennungen (IP-Adresse, Cookie-ID), biometrische Daten (Gesichtserkennung, Fingerabdruck), Gesundheitsdaten, finanzielle Informationen, politische Meinungen, religiöse Überzeugung.
=> recap
	
~ help
- Steuerung
	=> controls
- aktuelle Aufgabe
	=> task
- zurück
	=> start
	
~ controls
- Bewegen
	Verwenden Sie die Pfeiltasten oder w,a,s,d zum Bewegen. Mit der Leertaste können Sie springen.
	=> controls
- Werfen
	Mit [r] schalten Sie zwischen Kamera- und Wurfmodus um. Im Wurfmodus können Sie jederzeit Bälle werfen. Durch Bewegen der Mause können Sie zielen (Sie sollten ein Fadenkreuz sehen) und klicken zum Werfen.
	=> controls
- Objekte aufheben
	Um Objekte aufzuheben nutzen Sie die Taste [e]. Mit [q] können sie wieder abgelegt werden.
	=> controls
- Reden
	Um mit Personen zu reden, drücken Sie [Enter] oder [t]. Personen sind ansprechbar, wenn unten links eine Aufforderung zum Reden steht.
	=> controls
- Kamera
	Mit [r] schalten Sie zwischen Kamera- und Wurfmodus um. Im Kameramodus können Sie durch Bewegen der Maus die Kamera steueren, durch scrollen kann gezoomt werden. 
	=> controls
- zurück
	=> help

~ task
if DialogueState.currentTask == 1
	Sprechen Sie mit den Aliens, um verschiedene Definitionen von Künstlicher Intelligenz (KI) kennenzulernen.
	Zur Erinnerung: Start einer Unterhaltung mit [t] oder Enter.
elif DialogueState.currentTask == 2
	Laufen Sie weiter zur Wurfzone. Dort angekommen, können Sie die Ballons abwerfen, um zu entdecken, in was für Systemen KI bereits eingesetzt wird bzw. werden kann. Sammeln Sie danach die Batterien, Sie werden sie im weiteren Verlauf benötigen.
	Zur Erinnerung: Werfen mit [r] und Zielen mit der Maus (Fadenkreuz).
elif DialogueState.currentTask == 3
	In der folgenden Aufgabe geht es darum, die eben gesammelten Batterien zu ihren passenden Generatoren zuzuordnen. Dadurch wird das Raumschiff geladen und kann wieder starten. \nDie Batterien befinden sich im Inventar, welches sich mit [c] öffnen (und auch wieder schließen) lässt. Zum Zuordnen eine Batterie auswählen (über den Button) und anschließend zu den Generatoren transportieren und dort (mit [f]) wieder loslassen und einsetzen. \nJeder Generator steht für eine der vier Risikostufen. \nDie Batterien bilden je ein KI-System ab.
elif DialogueState.currentTask == 4
	Um in das Raumschiff zu gelangen, müssen Sie gleich als Passscode einmal alle personenbezogenen Daten auf dem Keypad auswählen. Zum Starten dieses Spiels, drücken Sie [k].
elif DialogueState.currentTask == 5
	Beantworten Sie die unten stehen Fragen, indem Sie sich auf das Feld stellen, dass zur richtigen Antwortmöglichkeit gehört. Bei richtiger Antwort öffnet sich die Tür und Sie glangen zur nächsten Frage.
else
	Lernen Sie die Steuerung kennen.
=> help